【分享成果，随喜正能量】无论已到哪里，少回头，多务实，当下不虚度，人生可无悔。

《VBA代码解决方案》这套教程是我最早推出的教程，目前已经是第二版修订了。这套教程定位于入门后的提高，在学习这套教程过程中，侧重点是要理解及掌握我的“积木编程”思想。要灵活运用教程中的实例像搭积木一下把自己喜欢的代码摆好。

这套教程共三册，一百四十七讲，内容覆盖较广，也是初级和中级间的过度教程，改版后的内容主要是提供程序源码文件及代码修正为32位和64位兼用代码。今后一段时间会给大家陆续推出。今日的内容是第7讲：利用Find方法查找

第七讲 使用Find方法，查找单元格

在Excel中使用查找对话框可以查找工作表中特定内容的单元格，而在VBA中则使用Find方法，这个方法是我比较喜欢的方法，在EXCEL中用LOOKUP可以的实现的内容均在使用FIND的方法之内。

1 VBA中利用FIND的代码实现单值查找实例

如下面的代码所示。

Sub myFind()

Dim StrFind As String

Dim Rng As Range

StrFind = InputBox("请输入要查找的值:")

If Trim(StrFind) <> "" Then

With Sheet1.Range("A:A")

Set Rng = .Find(What:=StrFind, _

After:=.Cells(.Cells.Count), _

LookIn:=xlValues, _

LookAt:=xlWhole, _

SearchOrder:=xlByRows, _

SearchDirection:=xlNext, _

MatchCase:=False)

If Not Rng Is Nothing Then

Application.Goto Rng, True

Else

MsgBox "没有找到该单元格!"

End If

End With

End If

End Sub

代码解读：myFind过程使用Find方法在工作表Sheet1的A列中查找InputBox函数对话框中所输入的值，并查找该值所在的第一个单元格。

• 应用于Range对象的Find方法在区域中查找特定信息，并返回Range对象，该对象代表用于查找信息的第一个单元格。如果未发现匹配单元格，就返回Nothing。

语法如下：

expression.Find(What, After, LookIn, LookAt, SearchOrder, SearchDirection, MatchCase, MatchByte, SerchFormat)

参数:

1) expression是必需的，该表达式返回一个Range对象。

2) What是必需的，要搜索的数据，可为字符串或任意数据类型。

3) After是可选的，表示搜索过程将从其之后开始进行的单元格，必须是区域中的单个单元格。查找时是从该单元格之后开始的，直到本方法绕回到指定的单元格时，才对其进行搜索。如果未指定本参数，搜索将从区域的左上角单元格之后开始。

在本例中将After参数设置为A列的最后一个单元格，所以查找时从A1单元格开始搜索。

4) LookIn是可选的，信息类型。xlValues对应 值；xlFormulas 对应 公式；xlComments对应 批注

5) LookAt是可选的，可为XlLookAt常量的xlWhole 或xlPart之一。

6) SearchOrder是可选的，可为XlSearchOrder常量的xlByRows或xlByColumns之一。

7) SearchDirection是可选的，搜索的方向，可为XlSearchDirection常量的xlNext或xlPrevious之一。

8) MatchCase是可选的，若为True，则进行区分大小写的查找。默认值为False。

9) MatchByte是可选的，仅在选择或安装了双字节语言支持时使用。若为True，则双字节字符仅匹配双字节字符。若为False，则双字节字符可匹配其等价的单字节字符。

10) SerchFormat是可选的，搜索的格式。

• 每次使用Find方法后，参数LookIn、LookAt、SearchOrder 和MatchByte的设置将保存。如果下次调用Find方法时不指定这些参数的值，就使用保存的值。因此每次使用该方法时请明确设置这些参数。
• 如果工作表的A列中存在重复的数值，那么需要使用FindNext方法或FindPrevious方法进行重复搜索，如下面的代码所示。

2 VBA中利用FIND的代码实现多值查找实例

Sub mynz_7() '第7讲 使用Find方法，查找单元格

Dim StrFind As String

Dim Rng As Range

Dim FindAddress As String

StrFind = InputBox("请输入要查找的值:")

If Trim(StrFind) <> "" Then

With Sheets("7").Range("A:A")

Set Rng = .Find(What:=StrFind, _

After:=.Cells(.Cells.Count), _

LookIn:=xlValues, _

LookAt:=xlWhole, _

SearchOrder:=xlByRows, _

SearchDirection:=xlNext, _

MatchCase:=False)

If Not Rng Is Nothing Then

FindAddress = Rng.Address

Do

Rng.Interior.ColorIndex = 6 '设置成黄色

Set Rng = .FindNext(Rng)

Loop While Not Rng Is Nothing And Rng.Address <> FindAddress

End If

End With

End If

End Sub

代码解析：RngFindNext过程在工作表Sheets(“7”)的A列中查找InputBox函数对话框中所输入的值，并将查到单元格底色设置成黄色。

第8行到第17行代码使用Find方法在工作表Sheet1的A列中查找。

第16行代码将查找到的第一个单元格地址赋给字符串变量FindAddress。

第18行代码将查找到的单元格底色设置成黄色。

第19行代码使用FindNext方法进行重复搜索。

• FindNext方法继续执行用Find方法启动的搜索。查找下一个匹配相同条件的单元格并返回代表单元格的Range对象，语法如下：

expression.FindNext(After)

参数

1）expression是必需的，返回一个Range对象。

2）After是可选的，指定一个单元格，查找将从该单元格之后开始。

第20行代码如果查找到的单元格地址等于字符串变量FindAddress所记录的地址，说明A列已搜索完毕，结束查找过程。

3 VBA中利用FIND的代码实现多值查找的代码运行

1）：代码截图：

2）开始运行：

3）返回结果：

今日内容回向：

1 FIND方法有哪些利用价值？

2 如何实现多值的查找？

我20多年的VBA实践经验，全部浓缩在下面的各个教程中：

第7套教程（共三册）：《VBA之EXCEL应用》：是对VBA基本的讲解

第1套教程（共三册）：《VBA代码解决方案》：是入门后的提高教程

第4套教程（16G）：VBA代码解决方案之视频（第一套的视频讲解）

第3套教程（共两册）：《VBA数组与字典解决方案》：是对数组和字典的专题讲解

第2套教程（共两册）：《VBA数据库解决方案》：是对数据库的专题讲解

第6套教程（共两册）：《VBA信息获取与处理》：讲解VBA的网络及跨程序应用

第5套教程（共两册）：VBA中类的解读和利用：类及接口技术的讲解

第8套教程（共三册）：VBA之Word应用（最新教程）：word中VBA的利用

上述教程的学习顺序：

① 7→1→3→2→6→5或者7→4→3→2→6→5。

② 7→8

• 如何学习VBA呢? 概括的说就是: 学习过程中要信、解、受、持，更要有回向的业力。无论您在学习的任何阶段，都要对照教程的知识点加持自己的实际工作，总会有丰厚的收获。